*Nov 05, 2012
*ECN S12-2667, Rev. B
*File Name: Si4465ADY_PS.txt and Si4465ADY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4465ADY D G S
M1  3  GX S S PMOS W=4438724u L=0.25u            
M2  S  GX S D NMOS W=4438724u L=0.65u 
RG  G  GX     2.5
R1  D  3      RTEMP 1E-3
CGS GX S      800E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 1.7E-8
+ RS     = 5E-3            RD     = 0          NSUB   = 5E15
+ KP     = 1.1E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 2E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 1.7E-8
+NSUB    = 1E17            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=800E-12 VJ=0.38 M=0.25
+RS=0.1 FC=0.5 IS=1E-12 TT=2.32E-8 N=1 BV=8.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=11E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS
