*June 13, 2005
*Doc. ID: 78676, S-51095, Rev. B
*File Name: Si4427BDY_PS.txt and Si4427BDY_PS.lib
.SUBCKT Si4427BDY 4 1 2
M1  3 1 2 2 PMOS W=5177523u L=0.25u          
M2  2 1 2 4 NMOS W=5177523u L=0.35u 
R1  4 3     RTEMP 3.6E-3
CGS 1 2     2400E-12
DBD 4 2     DBD
***************************************************************  
.MODEL  PMOS       PMOS  ( LEVEL  = 3           TOX    = 3E-8
+ RS     = 4.3E-3          RD     = 0           NSUB   = 3.1E16
+ KP     = 6E-6            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1.5E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS       NMOS  ( LEVEL  = 3           TOX    = 3E-8
+NSUB    = 1.8E17          TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=430E-12 VJ=0.38 M=0.32
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=30.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS