*Jan 23, 2006
*Doc. ID: 78599, S-60073, Rev. B
*File Name: Si7900AEDN_PS.txt and Si7900AEDN_PS.lib
.SUBCKT Si7900AEDN D G1 S1 G2 S2  
X1 D G1 S1 Si7900C1
X2 D G2 S2 Si7900C2
.ENDS Si7900AEDN
*Ch1
.SUBCKT Si7900C1 D G S
M1   3 5 S S NMOS W=1091546u L=0.50u  
M2   S 5 S D PMOS W=1091546u L=0.25u 
R1   D 3     RTEMP 11E-3  
CGS  5 S     600E-12
DBD  S D     DBD
xesd G 5 S   Si7900AEDN_ESD
************************************************************  
.MODEL  NMOS        NMOS ( LEVEL  = 3        TOX    = 1.7E-8
+ RS     = 7E-3            RD     = 0        NSUB   = 2.2E17  
+ KP     = 7.6E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3        TOX    = 1.7E-8
+NSUB    = 1E16            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=3900E-12 VJ=0.38  M=0.30
+RS=0.01 FC=0.1 IS=1E-12 TT=5.8E-8 N=1 BV=20.2)
************************************************************ 
.MODEL RTEMP RES (TC1=6E-3  TC2=5.5E-6)
************************************************************  
.ENDS Si7900C1
*Ch2
.SUBCKT Si7900C2 D G S
M1   3 5 S S NMOS W=1091546u L=0.50u  
M2   S 5 S D PMOS W=1091546u L=0.25u 
R1   D 3     RTEMP 11E-3  
CGS  5 S     600E-12
DBD  S D     DBD
xesd G 5 S   Si7900AEDN_ESD
************************************************************  
.MODEL  NMOS        NMOS ( LEVEL  = 3        TOX    = 1.7E-8
+ RS     = 7E-3            RD     = 0        NSUB   = 2.2E17  
+ KP     = 7.6E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3        TOX    = 1.7E-8
+NSUB    = 1E16            TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=3900E-12 VJ=0.38  M=0.30
+RS=0.01 FC=0.1 IS=1E-12 TT=5.8E-8 N=1 BV=20.2)
************************************************************ 
.MODEL RTEMP RES (TC1=6E-3  TC2=5.5E-6)
************************************************************  
.ENDS Si7900C2
.subckt Si7900AEDN_esd G 5 S
rleak G 9 64.25K $TC=0 
dleak 9 S dleak 
.MODEL dleak d (IS=2.178e-9 XTI=425.3 EG=1.17 T_MEASURED=25 TBV1=0 N=37.64 BV=50) 
rout G 10 98.37 $TC=-0.002
d3 11 10 dout 1.422 
d4 11 12 dout 1.422
d5 13 12 dout 1.472
d6 13 S  dout 1.472
.MODEL dout D (IS=3.03e-8 XTI=-35 EG=1.17 T_MEASURED=25 TBV1=-6.154e-4 N=2.494 BV=6.552)
rpoly G 5 2.2K TC=0.001
rd8 5 14 800.5 
d8 15 14 din  	
d9 15 S  din  	
.MODEL din D (IS=1e-11 XTI=-17.81 EG=1.17 T_MEASURED=25 TBV1=-1.575e-4 N=1.932 BV=6.351)
.ends Si7900AEDN_esd
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.