*May 16, 2005
*Doc. ID: 78434, S-50836, Rev. B
*File Name: Si4378DY_PS.txt and Si4378DY_PS.lib
.SUBCKT Si4378DY 4 1 2
M1  3 1 2 2 NMOS W=10594402u L=0.25u  
M2  2 1 2 4 PMOS W=10594402u L=0.25u 
R1  4 3     RTEMP 11E-4
CGS 1 2     5500E-12
DBD 2 4     DBD
*************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 3E-8
+ RS     = 8E-4           RD     = 0            NSUB   = 3.4E17  
+ KP     = 2.3E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 1E-4
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 3E-8
+NSUB    = 3E16           TPG    = -1)   
***************************************************************  
.MODEL DBD D (CJO=2300E-12 VJ=0.38 M=0.30
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=20.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS