*Jan 28, 2013
*ECN S13-0147, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet.  Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT SUM110P04-05 D G S
M1  3 G S S PMOS W=21247402u L=0.25u          
M2  S G S D NMOS W=21247402u L=0.40u
R1  D 3     RTEMP 13E-4
CGS G S     7000E-12
DBD D S     DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 5E-8
+ RS     = 22E-4           RD     = 0          NSUB   = 2.8E17
+ KP     = 3.8E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 5E-1
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5       TCV    = 4.3E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 5E-8
+NSUB    = 3E16            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=2400E-12 VJ=0.38 M=0.30
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=40.2)
*************************************************************** 
.MODEL RTEMP R (TC1=14E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS
