*Oct 24, 2005
*Doc. ID: 78271, S-52210, Rev. A
*File Name: Si1304BDL_PS.txt and Si1304BDL_PS.lib
.SUBCKT Si1304BDL 4 1 2
M1  3 1 2 2 NMOS W=84592u L=0.25u      
M2  2 1 2 4 PMOS W=84592u L=0.50u
R1  4 3     RTEMP 88E-3
CGS 1 2     100E-12
DBD 2 4     DBD
*************************************************************** 
.MODEL  NMOS       NMOS  ( LEVEL  = 3          TOX    = 3E-8
+ RS     = 90E-3           RD     = 0          NSUB   = 2.5E17
+ KP     = 3.1E-5          U0     = 650
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 1E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS  ( LEVEL  = 3          TOX    = 3E-8
+NSUB    = 2E17            TPG    = -1)           
 ************************************************************** 
.MODEL DBD D (CJO=28E-12 VJ=0.38 M=0.18
+RS=0.1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=30.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=7.5E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS