*Mar 25, 2013
*ECN S13-0598, Rev. C
*File Name: Si9433BDY_PS.txt, Si9433BDY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si9433BDY 4 1 2
M1  3 1 2 2 PMOS W=1193142u L=0.25u             
M2  2 1 2 4 NMOS W=1193142u L=0.35u 
R1  4 3     RTEMP 4E-3
CGS 1 2     500E-12
DBD 4 2     DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 3E-8
+ RS     = 12E-3           RD     = 0          NSUB   = 6E16
+ KP     = 7E-6            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 3E-8
+NSUB    = 1.8E17          TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=200E-12 VJ=0.38 M=0.25
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=20.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=10E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS   
