*Jan 28, 2013
*ECN S13-0184, Rev. C
*File Name: Si3442BDV_PS.txt, Si3442BDV_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si3442BDV 4 1 2
M1  3 1 2 2 NMOS W=345253u L=0.25u 
M2  2 1 2 4 PMOS W=345253u L=0.45u
R1  4 3     RTEMP 13E-3
CGS 1 2     200E-12
DBD 2 4     DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 3E-8
+ RS     = 17E-3          RD     = 0            NSUB   = 2.5E17  
+ KP     = 2E-5           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 1E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 3E-8
+NSUB    = 7E16           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=90E-12 VJ=0.38 M=0.26
+RS=0.1 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=20.5)
**************************************************************** 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS 

