*Dec 10, 2012
*ECN S12-2948, Rev. C
*File Name: Si7464DP_PS.txt, Si7464DP_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7464DP 4 1 2
M1  3 1 2 2 NMOS W=1244311u L=0.50u    
M2  2 1 2 4 PMOS W=1244311u L=0.35u  
R1  4 3     RTEMP 150E-3
CGS 1 2     80E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 5E-8
+ RS     = 39E-3           RD     = 0               NSUB   = 3.4E17   
+ kp     = 2.1E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 15E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL    = 3               TOX    = 5E-8
+NSUB    = 1.5E16          TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=100E-12 VJ=.38 M=0.32 
+FC=0.01 IS=1E-12 TT=11E-8 N=1 BV=100.2)
*************************************************************************
.MODEL RTEMP RES (TC1=7.7E-3 TC2=5.5E-6)
*************************************************************************
.ENDS     

