*Dec 10, 2012
*ECN S12-2960, Rev. C
*File Name: Si7415DN_PS.txt, Si7415DN_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7415DN 4 1 2
M1  3 1 2 2 PMOS W=1249340u L=0.50u
M2  2 1 2 4 NMOS W=1249340u L=0.75u
R1  4 3 RTEMP 32E-3
CGS 1 2 580E-12
DBD 4 2 DBD
*****************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3             TOX    = 7E-8
+ RS     = 12E-3           RD     = 0             NSUB   = 5.2E16   
+ KP     = 6.1E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 14E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3             TOX    = 7E-8
+NSUB    = 7E15            TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=560E-12 VJ=0.38 M=0.38
+RS=0.1 FC=0.5 IS=1E-12 TT=9E-8 N=1 BV=60.2)
*****************************************************************
.MODEL RTEMP RES (TC1=9E-3  TC2=5.5E-6)
*****************************************************************
.ENDS

