*Jun 17, 2013
*ECN S13-1098, Rev. C
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4896DY 4 1 2
M1  3 1 2 2 NMOS W=3862950u L=0.50u 
M2  2 1 2 4 PMOS W=3862950u L=0.75u
R1  4 3     RTEMP 8E-3
CGS 1 2     900E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS  (LEVEL  = 3               TOX    = 10E-8
+ RS     = 2.3E-3         RD     = 0               NSUB   = 1.15E17  
+ KP     = 0.9E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7            KAPPA  = 1E-1
+ ETA    = 1.0E-4         TPG    = 1  
+ IS     = 0              LD     = 0                           
+ CGSO   = 0              CGDO   = 0               CGBO   = 0 
+ TLEV   = 1              BEX    = -1.4            TCV    = 7.2E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL   = 3               TOX    = 10E-8
+NSUB    = 1.5E16         TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=600E-12  VJ=0.38  M=0.33
+RS=1 FC=0.5 IS=1E-12 TT=7E-8 N=1 BV=80.2)
*************************************************************************
.MODEL RTEMP R (TC1=8E-3   TC2=5.5E-6)
*************************************************************************
.ENDS
 

