*Jun 24, 2013
*ECN S13-1409, Rev. C
*File Name: SI4490dy_PS.txt, SI4490dy_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT SI4490dy 4 1 2
M1  3 1 2 2 NMOS W=3816184u L=0.50u
M2  2 1 2 4 PMOS W=3816184u L=0.60u
R1  4 3     RTEMP 62E-3
CGS 1 2     1000E-12
DBD 2 4     DBD
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3        TOX    = 10E-8
+ RS     = 4E-3            RD     = 0        NSUB   = 14.3E16   
+ KP     = 1.5E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 50E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS         PMOS (LEVEL  = 3        TOX    = 10E-8
+NSUB    = 0.5E16          TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=500E-12 VJ=0.38  M=0.40
+RS=0.01 FC=0.1 IS=1E-12 TT=4E-8 N=1 BV=200.5)
************************************************************ 
.MODEL RTEMP RES (TC1=7.5E-3   TC2=5.5E-6)
************************************************************  
.ENDS