*Jan 28, 2013
*ECN S13-0143, Rev. B
*File Name: Si3493BDV_PS.txt and Si3493BDV_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet.  Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si3493BDV D G S
M1  3  GX S S PMOS W=1734401u L=0.5u 
M2  S  GX S D NMOS W=1734401u L=1.6u  
RG  G  GX     6.5
R1  D  3      RTEMP 0.1E-3
CGS GX S      5E-12
DBD D  S      DBD
*****************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3             TOX    = 1.7E-8
+ RS     = 18E-3           RD     = 0             NSUB   = 2.9E15   
+ KP     = 2.2E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 1E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                     
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3             TOX    = 1.7E-8
+NSUB    = 1.4E16          TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=50E-12 VJ=0.38 M=0.33
+RS=0.1 FC=0.5 IS=1E-12 TT=2.31e-08 N=1 BV=21 )
*****************************************************************
.MODEL RTEMP RES (TC1=5E-3 TC2=5.5E-6)
*****************************************************************
.ENDS

