*Oct 29, 2012
*ECN S12-2582, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits. 
.SUBCKT Si3410DV D G S
M1  3  GX S S NMOS W=2282609u L=0.25u     
M2  S  GX S D PMOS W=2282609u L=0.14u      
RG  G  GX     2.4
R1  D  3      RTEMP 7E-3
CGS GX S      660E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 3E-8
+ RS     = 7.7E-3          RD     = 0           NSUB   = 6.7E17   
+ kp     = 1.6E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 3.9E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 3E-8
+NSUB    = 8E16            IS     = 0		TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=460E-12 VJ=0.38 M=0.37 
+FC=0.5 TT=1.51e-08 TREF=25 BV=31 
+RS=8.819e-03 N=1.075 IS=2.035e-12 IK=1000
+EG=1.127 XTI=4.307 TRS=2.060e-03 )
**************************************************************** 
.MODEL RTEMP R (TC1=9E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS
