*Nov 05, 2012
*ECN S12-2669, Rev. B
*File Name: Si4114DY_PS.txt, Si4114DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4114DY D G S
M1  3  GX S S NMOS W=5333200u L=0.250u              
M2  S  GX S D PMOS W=5333200u L=0.274u          
RG  G  GX     0.70
R1  D  3      RTEMP 2.3E-3
CGS GX S      2410E-12
DBD S  D      DBD
******************************************************* 
.MODEL  NMOS     NMOS (LEVEL  = 3       TOX    = 4E-8
+ RS     = 2.4E-3      RD     = 0       NSUB   = 2.5E17  
+ KP     = 2.1E-5      UO     = 650             
+ VMAX   = 0           XJ     = 5E-7    KAPPA  = 1E-1
+ ETA    = 1E-4        TPG    = 1  
+ IS     = 0           LD     = 0            
+ CGSO   = 0           CGDO   = 0       CGBO   = 0 
+ NFS    = 0.8E12      DELTA  = 0.1)
*******************************************************  
.MODEL  PMOS     PMOS (LEVEL  = 3       TOX    = 4E-8
+NSUB    = 4.5E16      IS     = 0       TPG    = -1)   
******************************************************* 
.MODEL DBD D (CJO=1630E-12 VJ=0.38 M=0.35
+FC=0.5 TT=1.23E-8 T_MEASURED=25 BV=20.5
+RS=3.772e-03 N=1.073 IS=2.039e-11 IKF=1000  
+EG=1.202 XTI=3.368e-01 TRS1=1.958e-03)
******************************************************* 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
******************************************************* 
.ENDS 
