*Nov 05, 2012
*ECN S12-2640, Rev. B
*File Name: Si4630DY_PS.txt and Si4630DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet.  Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4630DY D G S
M1  3  GX S S NMOS W=10594402u L=0.250u       
M2  S  GX S D PMOS W=10594402u L=0.256u       
RG  G  GX     1.5
R1  D  3      RTEMP 9.6E-4
CGS GX S      4700E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 4E-8
+ RS     = 10E-4           RD     = 0           NSUB   = 1E17   
+ kp     = 1E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 4E-8
+NSUB    = 4E16            IS     = 0		TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=2200E-12 VJ=0.38 M=0.36
+FC=0.5 TT=2.13e-08 T_MEASURED=25 BV=26
+RS=1.492e-03 N=1.062 IS=1.786e-11 IKF=1000
+EG=1.139 XTI=3.112 TRS1=1.217e-03 )
**************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS
