*Jan 28, 2013
*ECN S13-0149, Rev. B
*File Name: Si4116DY_PS.txt and Si4116DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet.  Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4116DY D G S
M1  3  GX S S NMOS W=3062590u L=0.25u       
M2  S  GX S D PMOS W=3062590u L=0.20u 
RG  G  GX     1.6
R1  D  3      RTEMP 4E-3
CGS GX S      1200E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3           TOX    = 3E-8
+ RS     = 3E-3           RD     = 0           NSUB   = 2.2E17  
+ KP     = 2.7E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 1E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0            
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3           TOX    = 3E-8
+NSUB    = 6E16           IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=780E-12 VJ=0.38 M=0.37
+FC=0.5 TT=1.24E-8 T_MEASURED=25 BV=26
+RS=7.263e-03 N=1.099 IS=2.524e-10 IKF=1000  
+EG=1.004 XTI=1.367 TRS1=8.169e-06)
**************************************************************** 
.MODEL RTEMP RES (TC1=6.5E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS 
