*Feb 04, 2013
*ECN S13-0237, Rev. B
*File Name: Si5418DU_PS.txt, Si5418DU_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si5418DU D G S
M1  3  GX S S NMOS W=2165279u L=0.25u      
M2  S  GX S D PMOS W=2165279u L=0.23u     
RG  G  GX     3.5
R1  D  3      RTEMP 4E-3
CGS GX S      900E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 7.5E-3         RD     = 0           NSUB   = 3.05E17  
+ KP     = 2.2E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 1E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0            
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5        TCV    = 4.1E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 3E16           IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=500E-12 VJ=0.38 M=0.40 
+FC=0.5 TT=1.52E-8 T_MEASURED=25 BV=30.5
+RS=9.199e-03 N=1.064 IS=1.805e-12 IKF=1000  
+EG=1.253 XTI=1.316e-01 TRS1=3.539e-03)
**************************************************************** 
.MODEL RTEMP RES (TC1=12E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS 
