*Mar 25, 2013
*ECN S13-0601, Rev. B
*File Name: SiA456DJ_PS.txt, SiA456DJ_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT SiA456DJ D G S
M1  3  GX S S NMOS W=428580u L=0.50u 
M2  S  GX S D PMOS W=428580u L=0.50u
RG  G  GX     2
R1  D  3      RTEMP 53.6E-2
CGS GX S      210E-12
DBD S  D      DBD
******************************************************************** 
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 4E-8
+ RS     = 53.6E-2         RD     = 0               NSUB   = 1.25E17   
+ kp     = 6E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 150E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
******************************************************************** 
.MODEL  PMOS       PMOS (  LEVEL    = 3             TOX    = 4E-8
+NSUB    = 9E15            IS     = 0	            TPG    = -1)   
******************************************************************** 
.MODEL DBD D (CJO=80E-12 VJ=0.38 M=0.46
+FC=0.5 TT=3.65E-8 T_MEASURED=25 BV=201
+RS=1.909e-02 N=1.607 IS=1.582e-08 IKF=1000  
+EG=1.077 XTI=1.68 TRS1=1.826e-13)
******************************************************************** 
.MODEL RTEMP RES (TC1=7.5E-3 TC2=5.5E-6)
******************************************************************** 
.ENDS
